10 DIMP(23),X(23),E(28),F(28),G(33),K(33)
15 DIMW$(7),L$(41),M$(12)
20 DATA SO,MO,DI,MI,DO,FR,SA
25 DATA JANUAR,FEBRUAR,MAERZ,APRIL,MAI,JUNI,JULI,AUGUST,SEPTEMBER,OKTOBER
30 DATA NOVEMBER,DEZEMBER
33 GOSUB1550
35 FORN=1TO23
39 REM
40 X(N)=SIN(6.283185307*(N-1)/23)
45 P(N)=INT(21.5+20*X(N))
50 NEXTN
55 FORN=1TO28
60 F(N)=SIN(6.283185307*(N-1)/28)
65 E(N)=INT(21.5+20*F(N))
70 NEXTN
75 FORN=1TO33
80 K(N)=SIN(6.283185307*(N-1)/33)
85 G(N)=INT(21.5+20*K(N))
90 NEXTN
95 FORN=1TO7
100 READW$(N)
105 NEXTN
110 FORN=1TO12
115 READM$(N)
120 NEXTN
125 FORN=1TO41
130 L$(N)=" "
135 NEXTN
140 REM IF VW=>2THENGOSUB5000:REM EINGABE ************************
145 GOSUB5000:REM MENUE   ************************
175 REM
180 GOSUB700
185 M=M4
190 D=1
195 Y=Y4
200 GOSUB515
205 S1=J
210 GOSUB700
215 L1=31
220 IFM4=12THEN250
225 GOSUB580
230 S3=N3
235 M=M4+1
240 GOSUB580
245 L1=N3-S3
250 B=J-S1+1
255 A=B+L1-1
260 CLOSE1:OPEN1,4:PRINT#1:PRINT#1,CHR$(14);"BIORYTHMUS  FUER  :  ";N$:PRINT#1
265 CLOSE1:OPEN1,4:PRINT#1:PRINT#1,"GEB. AM ";A1;".";A2;".";A3
270 PRINT#1:PRINT#1:PRINT#1,CHR$(15)
275 PRINT#1,"                                      MONAT :   ";M$(M4)
285 PRINT#1,CHR$(9);"INDEX                                   ",Y
290 CLOSE1:OPEN1,4:PRINT#1,CHR$(27);"D";CHR$(18);CHR$(0);
295 SK$="-09876-4321-9876-43210":SS$="1234+6789+1234+67890+":SL$=SK$+SS$
300 PRINT#1,CHR$(9);"     ";SL$;"       ":XC=1
305 REM
310 V=0
315 FORI=BTOA
320 V=V+1
325 J3=I-1
330 K1=INT(J3/23)
335 K2=J3-(K1*23)+1
340 K3=INT(J3/28)
345 K4=J3-(K3*28)+1
350 K5=INT(J3/33)
355 K6=J3-(K5*33)+1
360 P1=P(K2)
365 Q=E(K4)
370 R=G(K6)
375 O=X(K2)+F(K4)+K(K6)
380 O=INT(16666*(O+3))+1
385 L$(21)="."
390 L$(P1)="+":REM=PHYSISCHER RYHT.
395 L$(Q)="[211]":REM=EMOTINALER
400 L$(R)="?":REM=INTELLEKT
405 CLOSE1:OPEN1,4:REM           PRINT#1,CHR$(27);"D";CHR$(10);CHR$(0);
410 O$=STR$(O):IFLEN(O$)<5THENO$="X"+O$
413 IFLEN(O$)>5THENO$=RIGHT$(O$,5)
414 IFLEN(O$)=5ORXC=1THENPRINT#1,O$;
415 FORN=1TO41
420 CLOSE1:OPEN1,4:PRINT#1,CHR$(27);"D";CHR$(7);CHR$(0);
425 PRINT#1,CHR$(9);L$(N);
430 NEXTN
440 PRINT#1,V;W$(N2)
445 L$(P1)=" "
450 L$(Q)=" "
460 L$(R)=" "
465 N2=N2+1
470 IFN2<8THEN480
475 N2=1
480 NEXTI
485 REM      CLOSE1:OPEN1,4:PRINT#1,CHR$(27);"D";CHR$(18);CHR$(0);
490 PRINT#1:PRINT#1,CHR$(9);"     ";SL$:XC=0
495 REM
500 CLOSE1:OPEN1,4:PRINT#1,CHR$(27);"D";CHR$(23);CHR$(0);
505 GOSUB1660:REM ERKLAERUNG KURZ UND EVTL LANG EXPLAINING AUSDRUCKEN
510 RESTORE:GOTO33
515 IFM<3THEN535
520 M1=M-2
525 Y1=Y
530 GOTO545
535 M1=M+10
540 Y1=Y-1
545 C=INT(Y1/100)
550 D1=Y1-(C*100)
555 N4=INT((13*M1-1)/5)+D+D1+INT(D1/4)
560 N=N4+INT(C/4)-2*C+77
565 N1=INT(N/7)
570 N2=N-(N1*7)+1
575 RETURN
580 Y2=INT(Y/4)
585 Y3=Y-(Y2*4)
590 IFY3=0THEN600
595 GOTO650
600 Y2=INT(Y/100)
605 Y3=Y-(Y2*100)
610 IFY3=0THEN620
615 GOTO640
620 Y2=INT(Y/400)
625 Y3=Y-(Y2*400)
630 IFY3=0THEN640
635 GOTO650
640 L1=1
645 GOTO655
650 L1=0
655 N1=INT((3055*(M+2))/100)-91
660 L=0
665 IFM<3THEN690
670 IFL1=0THEN685
675 L=1
680 GOTO690
685 L=2
690 N3=N1+D-L
695 RETURN
700 IFM<3THEN720
705 M1=M-3
710 Y1=Y
715 GOTO730
720 M1=M+9
725 Y1=Y-1
730 C=INT(Y1/100)
735 D1=Y1-(C*100)
740 N=INT((146097*C)/4)+D+INT((1461*D1)/4)
745 J=N+1721119+INT((153*M1+2)/5)
750 RETURN
755 END
1000 PRINT#1:PRINT#1,CHR$(14):PRINT#1,"ERKLAERUNG:":PRINT#1:PRINT#1,CHR$(15)
1005 PRINT#1,"    WENN SIE DEN BIORHYTHMUS ALS ENTSCHEIDUNGSHILFE BENUTZEN,";
1010 PRINT#1,"SO SEHEN SIE,          WELCHER TAG GUENSTIG ODER UNGUENSTIG IST."
1011 PRINT#1
1020 PRINT#1,"    ES SIND 3 KURVEN ZU SEHEN: DER KOERPERLICHE-, DER EMOTIONALE";
1030 PRINT#1,"- UND DER ":PRINT#1,"     INTELLEKTRHYTHMUS."
1040 PRINT#1:PRINT#1,"IM AUSDRUCK UND DER ERKLAER";
1050 PRINT#1,"UNG WERDEN FOLGENDEN BEZEICHNUNGEN VERWENDET:"
1060 PRINT#1,"  KOERPERLICH = [+] ; EMOTIONAL = [*] ; INTELLEKT. = [?] ":PRINT#1
1070 PRINT#1,"     WERTEN SIE DIE DIAGRAMME NACH";
1080 PRINT#1," FOLGENDEN GESICHTSPUNKTEN AUS:"
1090 PRINT#1,"     PLUSPHASE IM '+' -RHYTHMUS:"
1100 PRINT#1,"           - ERHOEHTE KOERPERLICHE LEISTUNGSFAEHIGKEIT"
1110 PRINT#1,"           - ERHOEHTE ABWEHRBEREITSCHAFT GEGEN KRANKHEITEN"
1120 PRINT#1,"           - MEDIZINISCHE EINGRIFFE UND BEHANDLUNGEN, DIE DEN ";
1125 PRINT#1,"KOERPER ":PRINT#1,"           ";
1130 PRINT#1,"STARK BEANSPRUCHEN WERDEN IN DIESER PHASE EMPFOHLEN."
1140 PRINT#1,"    MINUS - PHASE IM KOERPER '+' - RYTHMUS "
1150 PRINT#1,"           - VERMINDERTE KOERPERLICHE LEISTUNGSFAEHIGKEIT"
1160 PRINT#1,"         - DIESE ZEIT NUTZEN ZUM AUSRUHEN UND ERHOLEN"
1170 PRINT#1,"    PLUSPHASE IM '*' -RHYTHMUS:"
1180 PRINT#1,"         - EBENFALLS POSITIVE KOERPERLICHE LEISTUNGSFAEHIGKEIT."
1190 PRINT#1,"         - DIESE WIRKUNG KANN SICH ZU DER WIRKUNG DES '+' RHTYM";
1200 PRINT#1,"US ADDIEREN ODER           NEUTRALISIEREN, JE NACH KONSTELLATION."
1210 PRINT#1,"         - ERHOEHTES SEELISCHES WOHLBEFINDEN"
1220 PRINT#1,"         - STARKES SEXUELLES VERLANGEN"
1230 PRINT#1,"         - GUTE ZEIT FUER SCHOEPFERISCHE TAETIGKEIT"
1240 PRINT#1,"   MINUSPHASE IM '*' -RHYTHMUS:"
1250 PRINT#1,"         - KOERPERLICHE BEFINDLICHKEIT ANALOG DEM '+' -RHYTHMUS."
1260 PRINT#1,"         - SEELISCHE BEDRUECKTHEIT, GEREIZTHEIT."
1270 PRINT#1,"         - VERMINDERTE SEXUALITAET."
1280 PRINT#1,"         - GERINGE KREATIVITAET."
1290 PRINT#1,"   PLUSPHASE IM I - RHYTHMUS:"
1300 PRINT#1,"         - HOHE GEISTIGE LEISTUNGSFAEHIGKEIT"
1310 PRINT#1,"         - WICHTIGE ARBEITEN, DIE KONZENTRATION, GEDAECHTNIS UND";
1320 PRINT#1," LOGISCHES ":PRINT#1,"           ";
1321 PRINT#1,"DENKEN ERFORDERN, SOLLTE MAN IN DIESER ZEIT PLANEN"
1330 PRINT#1,"   MINUS IN '?'- RHYTHMUS:"
1340 PRINT#1,"          - VERMINDERTE INTELLEKTUELLE LEISTUNGSFAEHIGKEIT."
1350 PRINT#1,"         - ZEIT ZUR GEISTIGEN ERHOLUNG BENUTZEN"
1360 PRINT#1,"         - KOERPERLICHE ARBEITEN BEVORZUGEN, SOFERN K - UND E -";
1370 PRINT#1,"RHYTHMUS DIES"
1375 PRINT#1,"           ERLAUBEN"
1380 PRINT#1," NULL - WERTE IM K - UND E - RHYTHMUS:"
1390 PRINT#1,"         - SIE HABEN IN BEIDEN RHYTMEN DIESELBE BEDEUTUNG:"
1400 PRINT#1,"         - SIE GEHEN MIT PLOETZLICHEN KOERPERLICHEN VERAENDER";
1410 PRINT#1,"UNGEN EINHER. Z.B.:"
1420 PRINT#1,"         - PLOETZLICHE KRANKHEITSAUSBRUECHE, FIEBER,";
1430 PRINT#1,"SCHLAFLOSIGKEIT"
1440 PRINT#1,"         - ABER AUCH POSITIVE VERAENDERUNGEN SIND MOEGLICH! Z.B."
1450 PRINT#1,"           GENESUNG,FIEBERABFALL, REGENERATION USW."
1460 PRINT#1,"  NULL TAGE IM I - RHYTHMUS:"
1470 PRINT#1,"         - REDUZIERTE GEISTIGE FAEHIGKEITEN U. AUFMERKSAMKEIT."
1480 PRINT#1,"         - DURCH KONZENTRATIONSMAENGEL ERHOEHTE UNFALLGEFAHR"
1490 PRINT#1
1500 PRINT#1,"        ZUR DETAILLIERTEREN AUSWERTUNG BENUTZEN SIE BITTE DIE"
1510 PRINT#1,"           UMFANGREICHE LITERATUR"
1520 PRINT#1
1530 CLOSE1:RETURN
1540 END
1550 REM START BIO
1560 REM *********
1570 POKE53281,5:PRINT"[158]":REM VORSPANN FARBE *********************
1580 CLOSE1:OPEN1,4:PRINT#1,CHR$(27);"D";CHR$(24);CHR$(0);:CLOSE1
1590 PRINT"[147]":POKE53281,8:PRINT"[158]"
1600 BR$=" ************ BIORHYTHMUS *************":
1610 SV$="           SOFTWARE BY WOLFRAM         "
1620 PRINTBR$:PRINT:PRINT:PRINTSV$:PRINT:PRINT:
1630 PRINTBR$:PRINT:PRINT:
1640 PRINT:PRINT"             BITTE WARTEN               "
1642 RETURN:REM NACH 35
1650 CLOSE1:OPEN1,4:PRINT#1,CHR$(9);"          BIORYTHMUS VON  : ";N$;"     *[160]";
1660 CLOSE1:OPEN1,4:PRINT#1,CHR$(27);"D";CHR$(23);CHR$(0);:REM GLUECK/ERKLAER**
1670 PRINT#1:REM *****KURZ ERKLAERUNG **************************************
1680 PRINT#1,"         VIEL GLUECK UND ALLES GUTE ";N$
1690 PRINT#1:PRINT#1,"         ";
1700 PRINT#1,"ZEICHENERKLAERUNG:":PRINT#1,
1710 PRINT#1,"         ";:PRINT#1,"DER INDEX ZAEHLT VON 1 BIS 99 999"
1720 PRINT#1,"         ";
1730 PRINT#1,"JE HOEHER DER INDEX IST, DESTO GUENSTIGER IST IHR PERS. RHYTHMUS"
1740 PRINT#1,"         ";
1750 PRINT#1,"?=INTELL.RHYTHMUS ;'[211]' = EMOTIONALER - UND '+' =KOERPERL. RHYTHMUS"
1760 RETURN:REM ZUM NEUEN START ETC ZEILE 505 ODER 510
1770 REM
1900 REM WIEDERGABE ZUM CHECK OB EINGABEAUTO1600-
1910 REM  IFD<>0THENDD=D:MM=M:YY=Y
1920 PRINT:PRINT:PRINT"[147]NAME= ";N$:PRINT:PRINT"GEBURTSTAG = ";D;". ";M;". ";Y
1930 PRINT:PRINT"AUSDRUCK FUER MONAT UND JAHR :";M4;". ";Y4:PRINT:
1940 RETURN
1950 END
2000 REM
3000 REM  IFVW>=2THEND=V1:M=V2:Y=V3:GOTO3042
3005 PRINT:PRINT"[147]NAME EINGEBEN":REM EINGABE VON NAMEN ETC *********************
3010 PRINT:PRINT:INPUTN$:REM***************
3020 PRINT:PRINT:PRINT"WANN SIND SIE GEBOREN ?"
3030 PRINT:PRINT"18,10,1950 BEDEUTET 18. OKT. 1950"
3040 PRINT:PRINT:INPUTD,M,Y
3042 A1=D:A2=M:A3=Y:PRINT:PRINT:
3050 PRINT"FUER WELCHEN MONAT AUSDRUCKEN?":PRINT:
3060 PRINT"4,1979 = APRIL 1979"
3070 PRINT:PRINT:INPUTM4,Y4
4000 REM WIEDERHOLUNG ZUR UEBERPREFUNG OB EINGABE RICHTIG
4010 PRINT:PRINT:PRINT"[147]NAME= ";N$:PRINT:PRINT"GEBURTSTAG = ";A1;". ";A2;". ";A3
4020 PRINT:PRINT"AUSDRUCK FUER MONAT UND JAHR :";M4;". ";Y4:PRINT:
4030 REM    RETURN:REM KONTROLLABFRAGE VOR AUSDRUCK
4040 GOSUB5000:REM ZUM MENUE
4043 RETURN:REM ZUM AUSDRUCK NACH KONTROLLE
5000 XC=0:PRINT"[147]              MENUE                     [146]":PRINT:PRINT
5010 PRINT"   AUSDRUCK -NUR GRAFIK-    = 1 "
5014 PRINT:PRINT"   DATENEINGABE FEHLER      = 2 "
5030 PRINT:PRINT"   DATEN E I N G E B E N    = 3 "
5040 PRINT:PRINT"   ERKLAERUNG -OHNE GRAFIK- = 5 "
5060 PRINT:PRINT"   ENDE                     = X"
5070 GETA$:IFA$=""THEN5070
5080 IFA$<>"1"ANDA$<>"2"ANDA$<>"3"ANDA$<>"4"ANDA$<>"5"ANDA$<>"X"THEN5070
5090 CLOSE1:OPEN1,4:PRINT#1,CHR$(27);"!";CHR$(21);CHR$(0);
5100 IFA$="2"THENGOSUB3000
5110 IFA$="1"THENPRINT:PRINT"B I T E   W A R T E N  * A U S G A B E":GOSUB175
5120 IFA$="3"THENGOSUB3000:RETURN
5130 IFA$="5"THENGOSUB 7000:CLOSE1:OPEN1,4:GOSUB1000:GOTO5000
5150 IFA$="X"THENEND
5170 GOTO5000
7000 PRINT"     DRUCKER JUSTIERT ?"
7002 PRINT"    DANN TASTE <RETURN>"
7005 GETJ$:IFJ$=""THEN7005
7010 IFJ$=CHR$(13)THEN RETURN
7020 IFJ$<>CHR$(13)THEN 5000
7030 END